Contract Source Code (Solidity Standard Json-Input format)

IDE

• Blockscan IDE
• 🤖 Code ReaderBeta

More Options

• Is this a proxy?
• Similar
• Submit Audit
• Compare

// SPDX-License-Identifier: BUSL-1.1
pragma solidity =0.8.17;

import {StorageSlot} from "@openzeppelin/contracts/utils/StorageSlot.sol";

import {ProxyOwnable} from "../utils/ProxyOwnable.sol";
import {BytesLib} from "../../lib/BytesLib.sol";
import {CallLib} from "../../lib/CallLib.sol";
import {IProxy} from "../IProxy.sol";
import {Proxy} from "../Proxy.sol";

/// @title Admin Upgradeable Proxy contract
/// @author 0xPhase
/// @dev Implementation of the Proxy contract in an owner upgradeable way
contract AdminUpgradeableProxy is ProxyOwnable, Proxy {
  using StorageSlot for bytes32;
  using BytesLib for bytes;

  bytes32 internal constant _IMPLEMENTATION_SLOT =
    bytes32(uint256(keccak256("proxy.implementation")) - 1);

  /// @dev Event emitted after upgrade of proxy
  /// @param _implementation New implementation for proxy
  event Upgraded(address indexed _implementation);

  /// @dev Initializes the upgradeable proxy with an initial implementation specified by `_target`.
  /// @param _owner Address of proxy owner
  /// @param _target Address of contract for proxy
  /// @param _initialCall Optional initial calldata
  constructor(address _owner, address _target, bytes memory _initialCall) {
    require(
      _owner != address(0),
      "AdminUpgradeableProxy: Owner cannot be 0 address"
    );

    require(
      _target != address(0),
      "AdminUpgradeableProxy: Target cannot be 0 address"
    );

    _setImplementation(_target);
    _initializeOwnership(_owner);

    if (_initialCall.length > 0) {
      CallLib.delegateCallFunc(_target, _initialCall);
    }
  }

  /// @dev Function to upgrade contract implementation
  /// @notice Only callable by the ecosystem owner
  /// @param _newImplementation Address of the new implementation
  /// @param _oldImplementationData Optional call data for old implementation before upgrade
  /// @param _newImplementationData Optional call data for new implementation after upgrade
  /// @custom:protected onlyOwner
  function upgradeTo(
    address _newImplementation,
    bytes calldata _oldImplementationData,
    bytes calldata _newImplementationData
  ) external onlyOwner {
    if (_oldImplementationData.length > 0) {
      CallLib.delegateCallFunc(implementation(msg.sig), _oldImplementationData);
    }

    _setImplementation(_newImplementation);

    if (_newImplementationData.length > 0) {
      CallLib.delegateCallFunc(implementation(msg.sig), _newImplementationData);
    }

    emit Upgraded(_newImplementation);
  }

  /// @inheritdoc IProxy
  function implementation(
    bytes4
  ) public view override returns (address _implementation) {
    _implementation = _IMPLEMENTATION_SLOT.getAddressSlot().value;
  }

  /// @inheritdoc IProxy
  function proxyType() public pure override returns (uint256 _type) {
    _type = 2;
  }

  /// @dev Function to upgrade contract implementation
  /// @param _newImplementation Address of the new implementation
  function _setImplementation(address _newImplementation) internal {
    _IMPLEMENTATION_SLOT.getAddressSlot().value = _newImplementation;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * _Available since v4.1 for `address`, `bool`, `bytes32`, `uint256`._
 * _Available since v4.9 for `string`, `bytes`._
 */
library StorageSlot {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity =0.8.17;

library BytesLib {
  /// @notice Slices the byte array
  /// @param _bytes The byte array
  /// @param _start The start of the slice
  /// @param _length The length of the slice
  /// @return The slice
  function slice(
    bytes memory _bytes,
    uint256 _start,
    uint256 _length
  ) internal pure returns (bytes memory) {
    require(_length + 31 >= _length, "BytesLib: Slice overflow");
    require(_bytes.length >= _start + _length, "BytesLib: Slice out of bounds");

    bytes memory tempBytes;

    // solhint-disable-next-line no-inline-assembly
    assembly {
      switch iszero(_length)
      case 0 {
        // Get a location of some free memory and store it in tempBytes as
        // Solidity does for memory variables.
        tempBytes := mload(0x40)

        // The first word of the slice result is potentially a partial
        // word read from the original array. To read it, we calculate
        // the length of that partial word and start copying that many
        // bytes into the array. The first word we copy will start with
        // data we don't care about, but the last `lengthmod` bytes will
        // land at the beginning of the contents of the new array. When
        // we're done copying, we overwrite the full first word with
        // the actual length of the slice.
        let lengthmod := and(_length, 31)

        // The multiplication in the next line is necessary
        // because when slicing multiples of 32 bytes (lengthmod == 0)
        // the following copy loop was copying the origin's length
        // and then ending prematurely not copying everything it should.
        let mc := add(add(tempBytes, lengthmod), mul(0x20, iszero(lengthmod)))
        let end := add(mc, _length)

        for {
          // The multiplication in the next line has the same exact purpose
          // as the one above.
          let cc := add(
            add(add(_bytes, lengthmod), mul(0x20, iszero(lengthmod))),
            _start
          )
        } lt(mc, end) {
          mc := add(mc, 0x20)
          cc := add(cc, 0x20)
        } {
          mstore(mc, mload(cc))
        }

        mstore(tempBytes, _length)

        //update free-memory pointer
        //allocating the array padded to 32 bytes like the compiler does now
        mstore(0x40, and(add(mc, 31), not(31)))
      }
      //if we want a zero-length slice let's just return a zero-length array
      default {
        tempBytes := mload(0x40)
        //zero out the 32 bytes slice we are about to return
        //we need to do it because Solidity does not garbage collect
        mstore(tempBytes, 0)

        mstore(0x40, add(tempBytes, 0x20))
      }
    }

    return tempBytes;
  }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity =0.8.17;

import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
import {Address} from "@openzeppelin/contracts/utils/Address.sol";

library CallLib {
  /// @notice Transfers the amount to the target address
  /// @param target The target address
  /// @param amount The amount to transfer
  function transferTo(address target, uint256 amount) internal {
    // solhint-disable-next-line avoid-low-level-calls
    (bool success, ) = payable(target).call{value: amount}("");

    require(success, "CallLib: Unsuccessful transfer");
  }

  /// @notice Calls an external function without value
  /// @param target The target contract
  /// @param data The calldata
  /// @return The result of the call
  function callFunc(
    address target,
    bytes memory data
  ) internal returns (bytes memory) {
    return callFunc(target, data, 0);
  }

  /// @notice Calls an external function with value
  /// @param target The target contract
  /// @param data The calldata
  /// @param value The value sent with the call
  /// @return The result of the call
  function callFunc(
    address target,
    bytes memory data,
    uint256 value
  ) internal returns (bytes memory) {
    require(
      address(this).balance >= value,
      "CallLib: insufficient balance for call"
    );

    // solhint-disable-next-line avoid-low-level-calls
    (bool success, bytes memory returndata) = target.call{value: value}(data);

    return verifyCallResult(success, returndata, target, "call");
  }

  /// @notice Calls an external function in current storage
  /// @param target The target contract
  /// @param data The calldata
  /// @return The result of the call
  function delegateCallFunc(
    address target,
    bytes memory data
  ) internal returns (bytes memory) {
    // solhint-disable-next-line avoid-low-level-calls
    (bool success, bytes memory returndata) = target.delegatecall(data);

    return verifyCallResult(success, returndata, target, "delegateCall");
  }

  /// @notice Calls an external function
  /// @param target The target contract
  /// @param data The calldata
  /// @return The result of the call
  function viewFunc(
    address target,
    bytes memory data
  ) internal view returns (bytes memory) {
    // solhint-disable-next-line avoid-low-level-calls
    (bool success, bytes memory returndata) = target.staticcall(data);

    return verifyCallResult(success, returndata, target, "view");
  }

  /// @notice Verifies if a contract call succeeded
  /// @param success If the call itself succeeded
  /// @param result The result of the call
  /// @param target The called contract
  /// @param method The method type, call or delegateCall
  /// @return The result of the call
  function verifyCallResult(
    bool success,
    bytes memory result,
    address target,
    string memory method
  ) internal view returns (bytes memory) {
    if (success) {
      if (result.length == 0) {
        // only check isContract if the call was successful and the return data is empty
        // otherwise we already know that it was a contract
        require(Address.isContract(target), "CallLib: call to non-contract");
      }

      return result;
    } else {
      reverts(
        result,
        string.concat(
          "CallLib: Function ",
          method,
          " reverted silently for ",
          Strings.toHexString(target)
        )
      );
    }
  }

  /// @notice Reverts on wrong result
  /// @param result The byte result of the call
  /// @param message The default revert message
  function reverts(bytes memory result, string memory message) internal pure {
    // Look for revert reason and bubble it up if present
    if (result.length > 0) {
      // The easiest way to bubble the revert reason is using memory via assembly
      // solhint-disable-next-line no-inline-assembly
      assembly {
        let result_size := mload(result)
        revert(add(32, result), result_size)
      }
    } else {
      revert(message);
    }
  }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity =0.8.17;

/// @title Proxy Interface
/// @author 0xPhase
/// @dev Allows for functionality to be loaded from another contract while running in local storage space
interface IProxy {
  /// @dev Function to receive ETH
  receive() external payable;

  /// @dev Fallback function to catch proxy calls
  /// returns This function will return whatever the implementation call returns
  fallback() external payable;

  /// @dev Tells the address of the implementation where every call will be delegated.
  /// @param sig The signature of the call
  /// @return _implementation The address of the implementation to which it will be delegated
  function implementation(
    bytes4 sig
  ) external view returns (address _implementation);

  /// @dev ERC897
  /// @return _type whether it is a forwarding (1) or an upgradeable (2) proxy
  function proxyType() external pure returns (uint256 _type);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity =0.8.17;

import {IProxy} from "./IProxy.sol";

/// @title Proxy Contract
/// @author 0xPhase
/// @dev Allows for functionality to be loaded from another contract while running in local storage space
abstract contract Proxy is IProxy {
  // @inheritdoc IProxy
  // solhint-disable-next-line no-empty-blocks
  receive() external payable {}

  // @inheritdoc IProxy
  fallback() external payable {
    _fallback();
  }

  /// @dev Function to handle delegating the proxy call to target implementation
  /// returns This function will return whatever the implementation call returns
  function _fallback() internal {
    address _impl = IProxy(this).implementation(msg.sig);

    require(_impl != address(0), "Proxy: Implementation not set");

    // solhint-disable-next-line no-inline-assembly
    assembly {
      // Copy msg.data. We take full control of memory in this inline assembly
      // block because it will not return to Solidity code. We overwrite the
      // Solidity scratch pad at memory position 0.
      calldatacopy(0, 0, calldatasize())

      // Call the implementation.
      // out and outsize are 0 because we don't know the size yet.
      let result := delegatecall(gas(), _impl, 0, calldatasize(), 0, 0)

      // Copy the returned data.
      returndatacopy(0, 0, returndatasize())

      switch result
      // delegatecall returns 0 on error.
      case 0 {
        revert(0, returndatasize())
      }
      default {
        return(0, returndatasize())
      }
    }
  }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity =0.8.17;

import {StorageSlot} from "@openzeppelin/contracts/utils/StorageSlot.sol";

abstract contract ProxyInitializable {
  using StorageSlot for bytes32;

  /// @notice Event emitted when a version is initalized
  /// @param version The initialized version
  event VersionInitialized(string indexed version);

  /// @notice Runs function if contract has been initialized
  /// @param version The version to initalize
  modifier initialize(string memory version) {
    StorageSlot.BooleanSlot storage disabledSlot = _disabledSlot()
      .getBooleanSlot();

    StorageSlot.BooleanSlot storage versionSlot = _versionSlot(version)
      .getBooleanSlot();

    if (!disabledSlot.value && !versionSlot.value) {
      _;

      emit VersionInitialized(version);
      versionSlot.value = true;
    }
  }

  /// @notice Internal function to disable all initializations
  function _disableInitialization() internal {
    StorageSlot.BooleanSlot storage disabledSlot = _disabledSlot()
      .getBooleanSlot();

    disabledSlot.value = true;
  }

  /// @notice Returns the slot for the disabled boolean
  /// @return The disabled boolean
  function _disabledSlot() internal pure returns (bytes32) {
    return bytes32(uint256(keccak256("proxy.initializable.disabled")) - 1);
  }

  /// @notice Returns the slot for the version initialized boolean
  /// @param version The version
  /// @return The version initialized boolean
  function _versionSlot(string memory version) internal pure returns (bytes32) {
    return
      bytes32(
        uint256(
          keccak256(
            bytes(string.concat("proxy.initializable.initialized.", version))
          )
        ) - 1
      );
  }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity =0.8.17;

import {StorageSlot} from "@openzeppelin/contracts/utils/StorageSlot.sol";

import {ProxyInitializable} from "./ProxyInitializable.sol";

abstract contract ProxyOwnable is ProxyInitializable {
  using StorageSlot for bytes32;

  bytes32 internal constant _OWNER_SLOT =
    bytes32(uint256(keccak256("proxy.ownable.owner")) - 1);

  /// @notice Event emitted when the ownership is transferred
  /// @param previousOwner The previous owner address
  /// @param newOwner The new owner address
  event OwnershipTransferred(
    address indexed previousOwner,
    address indexed newOwner
  );

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(
      msg.sender != address(0),
      "ProxyOwnable: Cannot be called by zero address"
    );

    require(owner() == msg.sender, "ProxyOwnable: Caller is not the owner");

    _;
  }

  /**
   * @dev Leaves the contract without owner. It will not be possible to call
   * `onlyOwner` functions anymore. Can only be called by the current owner.
   *
   * NOTE: Renouncing ownership will leave the contract without an owner,
   * thereby removing any functionality that is only available to the owner.
   */
  /// @custom:protected onlyOwner
  function renounceOwnership() public virtual onlyOwner {
    _transferOwnership(address(0));
  }

  /**
   * @dev Transfers ownership of the contract to a new account (`newOwner`).
   * Can only be called by the current owner.
   */
  /// @custom:protected onlyOwner
  function transferOwnership(address newOwner) public virtual onlyOwner {
    require(
      newOwner != address(0),
      "ProxyOwnable: New owner is the zero address"
    );

    _transferOwnership(newOwner);
  }

  /**
   * @dev Returns the address of the current owner.
   */
  function owner() public view virtual returns (address) {
    return _OWNER_SLOT.getAddressSlot().value;
  }

  /**
   * @dev Initializes the contract setting the firstOwner as the initial owner.
   */
  function _initializeOwnership(
    address firstOwner
  ) internal initialize("owner") {
    _transferOwnership(firstOwner);
  }

  /**
   * @dev Transfers ownership of the contract to a new account (`newOwner`).
   * Internal function without access restriction.
   */
  function _transferOwnership(address newOwner) internal virtual {
    address oldOwner = owner();
    _OWNER_SLOT.getAddressSlot().value = newOwner;

    emit OwnershipTransferred(oldOwner, newOwner);
  }
}

{
  "optimizer": {
    "enabled": true,
    "runs": 1000
  },
  "viaIR": true,
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "metadata": {
    "useLiteralContent": true
  },
  "libraries": {}
}

• No Contract Security Audit Submitted- Submit Audit Here

[{"inputs":[{"internalType":"address","name":"_owner","type":"address"},{"internalType":"address","name":"_target","type":"address"},{"internalType":"bytes","name":"_initialCall","type":"bytes"}],"stateMutability":"nonpayable","type":"constructor"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"previousOwner","type":"address"},{"indexed":true,"internalType":"address","name":"newOwner","type":"address"}],"name":"OwnershipTransferred","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"_implementation","type":"address"}],"name":"Upgraded","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"string","name":"version","type":"string"}],"name":"VersionInitialized","type":"event"},{"stateMutability":"payable","type":"fallback"},{"inputs":[{"internalType":"bytes4","name":"","type":"bytes4"}],"name":"implementation","outputs":[{"internalType":"address","name":"_implementation","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"owner","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"proxyType","outputs":[{"internalType":"uint256","name":"_type","type":"uint256"}],"stateMutability":"pure","type":"function"},{"inputs":[],"name":"renounceOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"newOwner","type":"address"}],"name":"transferOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"_newImplementation","type":"address"},{"internalType":"bytes","name":"_oldImplementationData","type":"bytes"},{"internalType":"bytes","name":"_newImplementationData","type":"bytes"}],"name":"upgradeTo","outputs":[],"stateMutability":"nonpayable","type":"function"},{"stateMutability":"payable","type":"receive"}]

0x608060405234620000c0576200149980380380916200001e82620000dc565b6080396060816080019112620000c0576200003862000152565b906200004362000169565b60c051926001600160401b038411620000c05782609f85011215620000c057836080015193620000738562000180565b936200008360405195866200012e565b85855260a08683010111620000c057620000b094620000aa9160a0602087019101620001ae565b620001d3565b604051610c0c90816200088d8239f35b600080fd5b50634e487b7160e01b600052604160045260246000fd5b6080601f91909101601f19168101906001600160401b038211908210176200010357604052565b6200010d620000c5565b604052565b604081019081106001600160401b038211176200010357604052565b601f909101601f19168101906001600160401b038211908210176200010357604052565b608051906001600160a01b0382168203620000c057565b60a051906001600160a01b0382168203620000c057565b6020906001600160401b0381116200019e575b601f01601f19160190565b620001a8620000c5565b62000193565b60005b838110620001c25750506000910152565b8181015183820152602001620001b1565b9091906001600160a01b0380821615620002ac578316156200024d577f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef7784680546001600160a01b0319166001600160a01b0385161790556200023490620006e3565b80516200023f575050565b6200024a916200030a565b50565b60405162461bcd60e51b815260206004820152603160248201527f41646d696e5570677261646561626c6550726f78793a205461726765742063616044820152706e6e6f742062652030206164647265737360781b6064820152608490fd5b60405162461bcd60e51b815260206004820152603060248201527f41646d696e5570677261646561626c6550726f78793a204f776e65722063616e60448201526f6e6f742062652030206164647265737360801b6064820152608490fd5b6000806200037893602081519101845af4903d156200037b573d6200032f8162000180565b906200033f60405192836200012e565b81523d6000602083013e5b60405192620003598462000112565b600c84526b19195b1959d85d1950d85b1b60a21b602085015262000460565b90565b60606200034a565b6049620004119193929360405194859171021b0b6362634b11d10233ab731ba34b7b7160751b6020840152620003c4815180926020603287019101620001ae565b82017f2072657665727465642073696c656e746c7920666f72200000000000000000006032820152620004018251809360208785019101620001ae565b010360298101855201836200012e565b565b156200041b57565b60405162461bcd60e51b815260206004820152601d60248201527f43616c6c4c69623a2063616c6c20746f206e6f6e2d636f6e74726163740000006044820152606490fd5b9092606091156200048757505081511562000479575090565b62000378903b151562000413565b909392916001600160a01b0316906200049f6200055c565b916030620004ad84620005b1565b536078620004bb84620005ce565b5360295b60018111620004ed575091620004e691620004e06200041195941562000621565b62000383565b906200066d565b9080600f6200052f9216601081101562000535575b6f181899199a1a9b1b9c1cb0b131b232b360811b901a620005248487620005e0565b5360041c9162000602565b620004bf565b6200053f6200059a565b62000502565b50634e487b7160e01b600052601160045260246000fd5b60405190606082016001600160401b038111838210176200058a575b604052602a8252604082602036910137565b62000594620000c5565b62000578565b50634e487b7160e01b600052603260045260246000fd5b602090805115620005c0570190565b620005ca6200059a565b0190565b602190805160011015620005c0570190565b906020918051821015620005f357010190565b620005fd6200059a565b010190565b801562000611575b6000190190565b6200061b62000545565b6200060a565b156200062957565b606460405162461bcd60e51b815260206004820152602060248201527f537472696e67733a20686578206c656e67746820696e73756666696369656e746044820152fd5b805190925015620006815750805190602001fd5b6044604051809262461bcd60e51b825260206004830152620006b38151809281602486015260208686019101620001ae565b601f01601f19168101030190fd5b620006db90602060405192828480945193849201620001ae565b810103902090565b60405190620006f28262000112565b60058252602082016437bbb732b960d91b81526040516200075a60408260208101947f70726f78792e696e697469616c697a61626c652e696e697469616c697a65642e8652620007498851809285850190620001ae565b81010360208101845201826200012e565b51902060001981019190821162000814575b620007a06200079c7f8022dd9fa38fb589bf926e46d07873257223d08ce285dac4a53971d2f0619f965460ff1690565b1590565b80620007fd575b620007b157505050565b6200041192620007c5620007cb9262000824565b620006c1565b7fd0d0608e931481535408f082f0bdc7b89de45589fbf2246d8ca6b5b5d458f1ac600080a2805460ff19166001179055565b506200080e6200079c835460ff1690565b620007a7565b6200081e62000545565b6200076c565b7f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa80546001600160a01b039283166001600160a01b0319821681179092559091167f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e0600080a356fe6080604052600436101561001e575b361561001c5761001c610574565b005b6000803560e01c9081630d74157714610099575080630f6d5d42146100905780634555d5c914610087578063715018a61461007e5780638da5cb5b146100755763f2fde38b0361000e576100706103e5565b61000e565b5061007061039e565b50610070610305565b506100706102e8565b50610070610150565b34610109576020366003190112610109576004357fffffffff00000000000000000000000000000000000000000000000000000000811603610109576001600160a01b037f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846541660805260206080f35b80fd5b6001600160a01b0381160361011d57565b600080fd5b9181601f8401121561011d5782359167ffffffffffffffff831161011d576020838186019501011161011d57565b503461011d57606036600319011261011d5760043561016e8161010c565b67ffffffffffffffff9060243582811161011d57610190903690600401610122565b9260443590811161011d576101a9903690600401610122565b90916101b633151561064d565b6001600160a01b03946101ed33877f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa5416146106be565b806102ad575b50507f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846805473ffffffffffffffffffffffffffffffffffffffff19166001600160a01b0385161790558061026c575b5050167fbc7cd75a20ee27fd9adebab32041f755214dbc6bffa90cc0225b39da2e5c2d3b600080a2005b61029f6102a592857f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846541692369161075a565b90610791565b503880610242565b61029f6102e092877f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846541692369161075a565b5038806101f3565b503461011d57600036600319011261011d57602060405160028152f35b503461011d576000806003193601126101095761032333151561064d565b807f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa80549073ffffffffffffffffffffffffffffffffffffffff196001600160a01b038316926103743385146106be565b1690557f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e08280a380f35b503461011d57600036600319011261011d5760206001600160a01b037f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa5416604051908152f35b503461011d57602036600319011261011d576004356104038161010c565b61040e33151561064d565b6001600160a01b0361044433827f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa5416146106be565b8116156104545761001c90610b62565b608460405162461bcd60e51b815260206004820152602b60248201527f50726f78794f776e61626c653a204e6577206f776e657220697320746865207a60448201527f65726f20616464726573730000000000000000000000000000000000000000006064820152fd5b50634e487b7160e01b600052604160045260246000fd5b90601f8019910116810190811067ffffffffffffffff8211176104f757604052565b6104ff6104be565b604052565b9081602091031261011d57516105198161010c565b90565b506040513d6000823e3d90fd5b1561053057565b606460405162461bcd60e51b815260206004820152601d60248201527f50726f78793a20496d706c656d656e746174696f6e206e6f74207365740000006044820152fd5b506040517f0d741577000000000000000000000000000000000000000000000000000000008152600080357fffffffff000000000000000000000000000000000000000000000000000000001660048301529081908190602081602481305afa908115610640575b8291610612575b506105f86001600160a01b0382161515610529565b368280378136915af43d82803e1561060e573d90f35b3d90fd5b610633915060203d8111610639575b61062b81836104d5565b810190610504565b386105e3565b503d610621565b61064861051c565b6105dc565b1561065457565b608460405162461bcd60e51b815260206004820152602e60248201527f50726f78794f776e61626c653a2043616e6e6f742062652063616c6c6564206260448201527f79207a65726f20616464726573730000000000000000000000000000000000006064820152fd5b156106c557565b608460405162461bcd60e51b815260206004820152602560248201527f50726f78794f776e61626c653a2043616c6c6572206973206e6f74207468652060448201527f6f776e65720000000000000000000000000000000000000000000000000000006064820152fd5b60209067ffffffffffffffff811161074d575b601f01601f19160190565b6107556104be565b610742565b9291926107668261072f565b9161077460405193846104d5565b82948184528183011161011d578281602093846000960137010152565b60008061051993602081519101845af4903d15610826573d6107b28161072f565b906107c060405192836104d5565b81523d6000602083013e5b604051926040840184811067ffffffffffffffff821117610819575b604052600c84527f64656c656761746543616c6c00000000000000000000000000000000000000006020850152610930565b6108216104be565b6107e7565b60606107cb565b60005b8381106108405750506000910152565b8181015183820152602001610830565b60496108e3919392936040519485917f43616c6c4c69623a2046756e6374696f6e200000000000000000000000000000602084015261089981518092602060328701910161082d565b82017f2072657665727465642073696c656e746c7920666f722000000000000000000060328201526108d4825180936020878501910161082d565b010360298101855201836104d5565b565b156108ec57565b606460405162461bcd60e51b815260206004820152601d60248201527f43616c6c4c69623a2063616c6c20746f206e6f6e2d636f6e74726163740000006044820152fd5b909260609115610953575050815115610947575090565b610519903b15156108e5565b909392916001600160a01b031690610969610a07565b91603061097584610a59565b53607861098184610a73565b5360295b600181116109ac5750916109a6916109a16108e3959415610ac6565b610850565b90610b11565b90807f3031323334353637383961626364656600000000000000000000000000000000600f6109f5931660108110156109fa575b1a6109eb8487610a84565b5360041c91610aa3565b610985565b610a02610a42565b6109e0565b604051906060820182811067ffffffffffffffff821117610a35575b604052602a8252604082602036910137565b610a3d6104be565b610a23565b50634e487b7160e01b600052603260045260246000fd5b602090805115610a67570190565b610a6f610a42565b0190565b602190805160011015610a67570190565b906020918051821015610a9657010190565b610a9e610a42565b010190565b8015610ab0576000190190565b634e487b7160e01b600052601160045260246000fd5b15610acd57565b606460405162461bcd60e51b815260206004820152602060248201527f537472696e67733a20686578206c656e67746820696e73756666696369656e746044820152fd5b805190925015610b245750805190602001fd5b6044604051809262461bcd60e51b825260206004830152610b54815180928160248601526020868601910161082d565b601f01601f19168101030190fd5b7f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa9081546001600160a01b03809216928373ffffffffffffffffffffffffffffffffffffffff198316179055167f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e0600080a356fea2646970667358221220a84ab84c913e4f7272921c7b36eac20c21d52e556d7a6ab3597fccec44c53a8664736f6c63430008110033000000000000000000000000a16814df2a7f2758e402f8c3a319cd790262af3f000000000000000000000000084da157c3cbd4f2c3a775f4633931e5a331c8bc000000000000000000000000000000000000000000000000000000000000006000000000000000000000000000000000000000000000000000000000000000e4444f5708000000000000000000000000c069b3faf13ae92dd058c65a8d8d0ec9f8975cf4000000000000000000000000000000000000000000000000000000000000006000000000000000000000000000000000000000000000000000000000000000a00000000000000000000000000000000000000000000000000000000000000006446f6c6c617200000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000004434153480000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000

0x6080604052600436101561001e575b361561001c5761001c610574565b005b6000803560e01c9081630d74157714610099575080630f6d5d42146100905780634555d5c914610087578063715018a61461007e5780638da5cb5b146100755763f2fde38b0361000e576100706103e5565b61000e565b5061007061039e565b50610070610305565b506100706102e8565b50610070610150565b34610109576020366003190112610109576004357fffffffff00000000000000000000000000000000000000000000000000000000811603610109576001600160a01b037f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846541660805260206080f35b80fd5b6001600160a01b0381160361011d57565b600080fd5b9181601f8401121561011d5782359167ffffffffffffffff831161011d576020838186019501011161011d57565b503461011d57606036600319011261011d5760043561016e8161010c565b67ffffffffffffffff9060243582811161011d57610190903690600401610122565b9260443590811161011d576101a9903690600401610122565b90916101b633151561064d565b6001600160a01b03946101ed33877f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa5416146106be565b806102ad575b50507f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846805473ffffffffffffffffffffffffffffffffffffffff19166001600160a01b0385161790558061026c575b5050167fbc7cd75a20ee27fd9adebab32041f755214dbc6bffa90cc0225b39da2e5c2d3b600080a2005b61029f6102a592857f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846541692369161075a565b90610791565b503880610242565b61029f6102e092877f24ed44ee9374370fd3aa7c8b1abf58827504c20f65246b17d2b9e7e1aef77846541692369161075a565b5038806101f3565b503461011d57600036600319011261011d57602060405160028152f35b503461011d576000806003193601126101095761032333151561064d565b807f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa80549073ffffffffffffffffffffffffffffffffffffffff196001600160a01b038316926103743385146106be565b1690557f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e08280a380f35b503461011d57600036600319011261011d5760206001600160a01b037f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa5416604051908152f35b503461011d57602036600319011261011d576004356104038161010c565b61040e33151561064d565b6001600160a01b0361044433827f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa5416146106be565b8116156104545761001c90610b62565b608460405162461bcd60e51b815260206004820152602b60248201527f50726f78794f776e61626c653a204e6577206f776e657220697320746865207a60448201527f65726f20616464726573730000000000000000000000000000000000000000006064820152fd5b50634e487b7160e01b600052604160045260246000fd5b90601f8019910116810190811067ffffffffffffffff8211176104f757604052565b6104ff6104be565b604052565b9081602091031261011d57516105198161010c565b90565b506040513d6000823e3d90fd5b1561053057565b606460405162461bcd60e51b815260206004820152601d60248201527f50726f78793a20496d706c656d656e746174696f6e206e6f74207365740000006044820152fd5b506040517f0d741577000000000000000000000000000000000000000000000000000000008152600080357fffffffff000000000000000000000000000000000000000000000000000000001660048301529081908190602081602481305afa908115610640575b8291610612575b506105f86001600160a01b0382161515610529565b368280378136915af43d82803e1561060e573d90f35b3d90fd5b610633915060203d8111610639575b61062b81836104d5565b810190610504565b386105e3565b503d610621565b61064861051c565b6105dc565b1561065457565b608460405162461bcd60e51b815260206004820152602e60248201527f50726f78794f776e61626c653a2043616e6e6f742062652063616c6c6564206260448201527f79207a65726f20616464726573730000000000000000000000000000000000006064820152fd5b156106c557565b608460405162461bcd60e51b815260206004820152602560248201527f50726f78794f776e61626c653a2043616c6c6572206973206e6f74207468652060448201527f6f776e65720000000000000000000000000000000000000000000000000000006064820152fd5b60209067ffffffffffffffff811161074d575b601f01601f19160190565b6107556104be565b610742565b9291926107668261072f565b9161077460405193846104d5565b82948184528183011161011d578281602093846000960137010152565b60008061051993602081519101845af4903d15610826573d6107b28161072f565b906107c060405192836104d5565b81523d6000602083013e5b604051926040840184811067ffffffffffffffff821117610819575b604052600c84527f64656c656761746543616c6c00000000000000000000000000000000000000006020850152610930565b6108216104be565b6107e7565b60606107cb565b60005b8381106108405750506000910152565b8181015183820152602001610830565b60496108e3919392936040519485917f43616c6c4c69623a2046756e6374696f6e200000000000000000000000000000602084015261089981518092602060328701910161082d565b82017f2072657665727465642073696c656e746c7920666f722000000000000000000060328201526108d4825180936020878501910161082d565b010360298101855201836104d5565b565b156108ec57565b606460405162461bcd60e51b815260206004820152601d60248201527f43616c6c4c69623a2063616c6c20746f206e6f6e2d636f6e74726163740000006044820152fd5b909260609115610953575050815115610947575090565b610519903b15156108e5565b909392916001600160a01b031690610969610a07565b91603061097584610a59565b53607861098184610a73565b5360295b600181116109ac5750916109a6916109a16108e3959415610ac6565b610850565b90610b11565b90807f3031323334353637383961626364656600000000000000000000000000000000600f6109f5931660108110156109fa575b1a6109eb8487610a84565b5360041c91610aa3565b610985565b610a02610a42565b6109e0565b604051906060820182811067ffffffffffffffff821117610a35575b604052602a8252604082602036910137565b610a3d6104be565b610a23565b50634e487b7160e01b600052603260045260246000fd5b602090805115610a67570190565b610a6f610a42565b0190565b602190805160011015610a67570190565b906020918051821015610a9657010190565b610a9e610a42565b010190565b8015610ab0576000190190565b634e487b7160e01b600052601160045260246000fd5b15610acd57565b606460405162461bcd60e51b815260206004820152602060248201527f537472696e67733a20686578206c656e67746820696e73756666696369656e746044820152fd5b805190925015610b245750805190602001fd5b6044604051809262461bcd60e51b825260206004830152610b54815180928160248601526020868601910161082d565b601f01601f19168101030190fd5b7f039c1dfe27e8f8057bf4f5a7c6af2df79b436e250f4dec5229c8f29efc2a1dfa9081546001600160a01b03809216928373ffffffffffffffffffffffffffffffffffffffff198316179055167f8be0079c531659141344cd1fd0a4f28419497f9722a3daafe3b4186f6b6457e0600080a356fea2646970667358221220a84ab84c913e4f7272921c7b36eac20c21d52e556d7a6ab3597fccec44c53a8664736f6c63430008110033