// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import "@uniswap/v3-core/contracts/interfaces/IUniswapV3Factory.sol";

import "./YesNoToken.sol";
import "./OraclePausable.sol";
import "./MarketEnums.sol";
import "./BondConstants.sol";
import "./EscalationStructs.sol";
import "./interfaces/ITruthMarketManager.sol";
import "./interfaces/ITruthMarket.sol";
import "./interfaces/IOracleBonds.sol";
import "./interfaces/IOracleCouncil.sol";
import "./interfaces/IEscalation.sol";
import "./interfaces/IBlacklistable.sol";

contract TruthMarket is Initializable, OwnableUpgradeable, OraclePausable, ReentrancyGuardUpgradeable {
    using SafeERC20 for IERC20;
    using SafeERC20 for IERC20Metadata;

    struct StatusChange {
        MarketStatus status;
        uint256 timestamp;
        uint256 outcome;
    }

    string public constant VERSION = "1.1.0";

    uint256 private constant _HUNDRED = 100;
    uint256 private constant _ONE_PERCENT = 1e16;
    uint256 private constant _HUNDRED_PERCENT = 1e18;

    uint256 private constant _YES = 1;
    uint256 private constant _NO = 2;
    uint256 private constant _CANCELED = 3;

    uint256 public winningPosition;

    uint256 public endOfTrading;

    uint256 public createdAt;
    uint256 public resolutionProposedAt;
    uint256 public disputedAt;
    uint256 public councilDecisionAt;
    uint256 public escalatedDisputeAt;
    uint256 public finalizedAt;

    uint256 public firstChallengePeriod;
    uint256 public secondChallengePeriod;

    uint256 public yesNoTokenCap;

    uint256 public resolverBondAmount;
    uint256 public disputerBondAmount;
    uint256 public escalatorBondAmount;

    ITruthMarketManager public marketManager;
    IOracleBonds public oracleBonds;
    IOracleCouncil public oracleCouncil;
    IEscalation public escalation;

    string public marketQuestion;
    string public marketSource;
    string public additionalInfo;

    IERC20Metadata public paymentToken;
    YesNoToken public yesToken;
    YesNoToken public noToken;
    uint256 private _paymentTokenDecimals;
    uint256 private _tokenDecimals;
    uint256 public rewardAmount;

    uint24 public constant POOL_FEE = 3000; // 0.3%

    address public yesPool;
    address public noPool;

    IERC20 public rewardToken;

    MarketStatus public currentStatus;
    StatusChange[] public statusHistory;

    bool public bondSettled;

    event BondsSettled(address market, uint256 winningPosition);
    event MarketStatusUpdated(MarketStatus from, MarketStatus to, uint256 outcome);
    event TokensMinted(address indexed user, uint256 amount);
    event TokensBurned(address indexed user, uint256 amount);
    event TokensRedeemed(address indexed user, uint256 amount);
    event WithdrawnFromCanceledMarket(address indexed user, uint256 yesAmount, uint256 noAmount, uint256 paymentAmount);
    event YesNoTokenCapChanged(uint256 yesNoTokenCap);
    event EndOfTradingChanged(uint256 endOfTrading);
    event FirstChallengePeriodChanged(uint256 firstChallengePeriod);
    event SecondChallengePeriodChanged(uint256 secondChallengePeriod);
    event RewardReceiverBlacklisted(address indexed token, address indexed account);

    error TokenCapExceeded();
    error MarketNotInTradingPhase();
    error MarketNotDisputed();
    error MarketNotFinalized();
    error MarketNotCanceled();
    error MarketFinalized();
    error InvalidOutcome(uint256 outcome);
    error InvalidStatusTransition(MarketStatus from, MarketStatus to);
    error BondsAlreadySettled();
    error NoTokensToWithdraw();
    error InvalidBondAmount();
    error InvalidChallengePeriod();
    error InvalidAddress();

    // Constructor //////////////////////////////////////////////////////

    /// @notice Initializes a new market with the specified parameters
    /// @param _marketQuestion The question that the market will resolve
    /// @param _marketSource The source that will be used to verify the outcome
    /// @param _additionalInfo Additional information about the market
    /// @param _endOfTrading The timestamp when trading will end
    /// @param _yesNoTokenCap The maximum amount of YES/NO tokens that can be minted
    /// @param _paymentToken The token used for payments
    /// @param _yesToken The YES token contract address
    /// @param _noToken The NO token contract address
    /// @param _rewardToken The token used for rewards
    /// @param _rewardAmount The amount of reward tokens
    function initialize(
        string memory _marketQuestion,
        string memory _marketSource,
        string memory _additionalInfo,
        uint256 _endOfTrading,
        uint256 _yesNoTokenCap,
        address _paymentToken,
        address _yesToken,
        address _noToken,
        address _rewardToken,
        uint256 _rewardAmount
    ) external initializer {
        __Ownable_init();
        __ReentrancyGuard_init();
        marketManager = ITruthMarketManager(msg.sender);
        oracleBonds = IOracleBonds(marketManager.oracleBonds());
        if (address(oracleBonds) == address(0)) {
            revert InvalidAddress();
        }
        oracleCouncil = IOracleCouncil(marketManager.oracleCouncilAddress());
        if (address(oracleCouncil) == address(0)) {
            revert InvalidAddress();
        }
        escalation = IEscalation(marketManager.escalationAddress());
        if (address(escalation) == address(0)) {
            revert InvalidAddress();
        }

        _initializeWithParameters(_marketQuestion, _marketSource, _additionalInfo, _endOfTrading, _yesNoTokenCap);
        resolverBondAmount = marketManager.resolverBondAmount();
        disputerBondAmount = marketManager.disputerBondAmount();
        escalatorBondAmount = marketManager.escalatorBondAmount();
        if (resolverBondAmount == 0 || disputerBondAmount == 0 || escalatorBondAmount == 0) {
            revert InvalidBondAmount();
        }

        firstChallengePeriod = marketManager.firstChallengePeriod();
        secondChallengePeriod = marketManager.secondChallengePeriod();
        if (firstChallengePeriod == 0 || secondChallengePeriod == 0) {
            revert InvalidChallengePeriod();
        }

        paymentToken = IERC20Metadata(_paymentToken);
        yesToken = YesNoToken(_yesToken);
        noToken = YesNoToken(_noToken);

        _paymentTokenDecimals = paymentToken.decimals();
        _tokenDecimals = yesToken.decimals();

        IUniswapV3Factory uniswapV3Factory = IUniswapV3Factory(marketManager.uniswapV3Factory());

        // Check if pool exists first, if not then create
        address existingYesPool = uniswapV3Factory.getPool(_yesToken, _paymentToken, POOL_FEE);
        yesPool = existingYesPool == address(0)
            ? uniswapV3Factory.createPool(_yesToken, _paymentToken, POOL_FEE)
            : existingYesPool;

        address existingNoPool = uniswapV3Factory.getPool(_noToken, _paymentToken, POOL_FEE);
        noPool = existingNoPool == address(0)
            ? uniswapV3Factory.createPool(_noToken, _paymentToken, POOL_FEE)
            : existingNoPool;

        bondSettled = false;

        rewardToken = IERC20(_rewardToken);
        rewardAmount = _rewardAmount;

        currentStatus = MarketStatus.Created;
        statusHistory.push(StatusChange(MarketStatus.Created, block.timestamp, 0));
    }

    // External functions //////////////////////////////////////////////

    function proposeResolution(uint256 _outcome) external onlyOwner {
        if (_outcome > _CANCELED || _outcome == 0) {
            revert InvalidOutcome(_outcome);
        }
        winningPosition = _outcome;
        resolutionProposedAt = block.timestamp;

        // resolver should be punish and OpenForResolution was not set to history
        if (currentStatus == MarketStatus.ResetByCouncil) {
            disputedAt = 0;
            councilDecisionAt = 0;

            IOracleCouncil.Dispute memory lastDispute = oracleCouncil.getLastClosedDispute(address(this));
            oracleBonds.sendBondFromMarketToSafeBox(
                address(this), BondConstants.RESOLVER_BOND, lastDispute.disputorAddress
            );
            oracleBonds.issueBondsBackToDisputor(address(this), lastDispute.disputorAddress);
            marketManager.resetMarketStatus(address(this));
        }

        _updateStatus(MarketStatus.ResolutionProposed, _outcome);
    }

    function raiseDispute() external onlyOwner {
        disputedAt = block.timestamp;

        _updateStatus(MarketStatus.DisputeRaised, 0);
    }

    function resolveMarketByCouncil(uint256 _outcome) external onlyOwner {
        winningPosition = _outcome;
        councilDecisionAt = block.timestamp;

        _updateStatus(MarketStatus.SetByCouncil, _outcome);
    }

    function resetMarketByCouncil(bool _returnToOpenForResolution) external onlyOwner {
        if (_returnToOpenForResolution) {
            winningPosition = 0;
            resolutionProposedAt = 0;
            disputedAt = 0;
            councilDecisionAt = 0;
            _updateStatus(MarketStatus.OpenForResolution, 0);
            // issue bonds back to disputor and resolver since no one is punished
            oracleBonds.issueBondsBackToResolver(address(this));
            oracleBonds.issueBondsBackToDisputor(
                address(this), oracleCouncil.getLastClosedDispute(address(this)).disputorAddress
            );
            marketManager.resetMarketStatus(address(this));
        } else {
            councilDecisionAt = block.timestamp;
            _updateStatus(MarketStatus.ResetByCouncil, 0);
        }
    }

    function raiseEscalatedDispute() external onlyOwner {
        escalatedDisputeAt = block.timestamp;
        _updateStatus(MarketStatus.EscalatedDisputeRaised, 0);
    }

    function resolveMarketByEscalation(uint256 _outcome) external onlyOwner {
        if (_outcome > _CANCELED || _outcome == 0) {
            revert InvalidOutcome(_outcome);
        }

        winningPosition = _outcome;
        finalizedAt = block.timestamp;

        _updateStatus(MarketStatus.Finalized, _outcome);
    }

    function resetMarketByEscalation() external onlyOwner {
        winningPosition = 0;
        resolutionProposedAt = 0;
        disputedAt = 0;
        councilDecisionAt = 0;
        escalatedDisputeAt = 0;

        EscalatedDispute memory lastEscalation = escalation.getEscalatedDispute(address(this));
        IOracleCouncil.Dispute memory lastDispute = oracleCouncil.getLastClosedDispute(address(this));

        _handleBondsForEscalation(lastEscalation, lastDispute);

        marketManager.resetMarketStatus(address(this));

        _updateStatus(MarketStatus.OpenForResolution, 0);
    }

    function setYesNoTokenCap(uint256 _yesNoTokenCap) external onlyOwner {
        yesNoTokenCap = _yesNoTokenCap;
        emit YesNoTokenCapChanged(_yesNoTokenCap);
    }

    function setEndOfTrading(uint256 _endOfTrading) external onlyOwner {
        // check if market is in trading phase
        if (getCurrentStatus() != MarketStatus.Created) {
            revert MarketNotInTradingPhase();
        }
        endOfTrading = _endOfTrading;
        emit EndOfTradingChanged(_endOfTrading);
    }

    function setFirstChallengePeriod(uint256 _firstChallengePeriod) external onlyOwner {
        firstChallengePeriod = _firstChallengePeriod;
        emit FirstChallengePeriodChanged(_firstChallengePeriod);
    }

    function setSecondChallengePeriod(uint256 _secondChallengePeriod) external onlyOwner {
        secondChallengePeriod = _secondChallengePeriod;
        emit SecondChallengePeriodChanged(_secondChallengePeriod);
    }

    // mint is not available after market is finalized
    function mint(uint256 paymentTokenAmount) external notPaused nonReentrant {
        if (getCurrentStatus() == MarketStatus.Finalized) {
            revert MarketFinalized();
        }

        uint256 tokenAmount = paymentTokenAmount * (10 ** _tokenDecimals) / (10 ** _paymentTokenDecimals);

        // Check if total supply of both Yes and No tokens would exceed the cap
        // Since YesNoToken inherits from ERC20Burnable, users can burn Yes or No tokens independently
        // This can lead to an imbalance between Yes and No token total supplies
        // Example: When Yes = 80, No = 90, if we only check Yes tokens, users can still mint 20 more tokens
        // This would result in Yes = 100, No = 110, causing No tokens to exceed the cap
        if (yesToken.totalSupply() + tokenAmount > yesNoTokenCap || noToken.totalSupply() + tokenAmount > yesNoTokenCap) {
            revert TokenCapExceeded();
        }

        paymentToken.safeTransferFrom(msg.sender, address(this), paymentTokenAmount);

        yesToken.mint(msg.sender, tokenAmount);
        noToken.mint(msg.sender, tokenAmount);

        emit TokensMinted(msg.sender, tokenAmount);
    }

    function burn(uint256 amount) external notPaused nonReentrant {
        if (getCurrentStatus() == MarketStatus.Finalized) {
            revert MarketFinalized();
        }
        uint256 paymentTokenAmount = amount * (10 ** _paymentTokenDecimals) / (10 ** _tokenDecimals);
        yesToken.burnFrom(msg.sender, amount);
        noToken.burnFrom(msg.sender, amount);
        paymentToken.safeTransfer(msg.sender, paymentTokenAmount);
        emit TokensBurned(msg.sender, amount);
    }

    function redeem(uint256 amount) external notPaused nonReentrant {
        if (getCurrentStatus() != MarketStatus.Finalized) {
            revert MarketNotFinalized();
        }
        if (winningPosition != _YES && winningPosition != _NO) {
            revert InvalidOutcome(winningPosition);
        }

        // set market status to finalized if not already
        if (currentStatus != MarketStatus.Finalized) {
            _setStatusToFinalized(winningPosition);
        }

        if (!bondSettled) {
            _settleBonds();
        }
        // amount is in yesToken decimals, so we need to convert to paymentToken decimals
        uint256 paymentTokenAmount = amount * (10 ** _paymentTokenDecimals) / (10 ** _tokenDecimals);

        if (winningPosition == _YES) {
            // YES won
            yesToken.burnFrom(msg.sender, amount);
        } else {
            // NO won
            noToken.burnFrom(msg.sender, amount);
        }

        paymentToken.safeTransfer(msg.sender, paymentTokenAmount);
        emit TokensRedeemed(msg.sender, amount);
    }

    function withdrawFromCanceledMarket() external notPaused nonReentrant {
        if (getCurrentStatus() != MarketStatus.Finalized) {
            revert MarketNotFinalized();
        }
        if (winningPosition != _CANCELED) {
            revert MarketNotCanceled();
        }

        // set market status to finalized if not already
        if (currentStatus != MarketStatus.Finalized) {
            _setStatusToFinalized(winningPosition);
        }

        if (!bondSettled) {
            _settleBonds();
        }

        uint256 yesBalance = yesToken.balanceOf(msg.sender);
        uint256 noBalance = noToken.balanceOf(msg.sender);
        uint256 totalBalance = yesBalance + noBalance;

        if (totalBalance == 0) {
            revert NoTokensToWithdraw();
        }

        // Calculate the withdrawal amount at 0.5 USDC per token
        uint256 paymentTokenAmount = totalBalance * (5 * 10 ** (_paymentTokenDecimals - 1)) / (10 ** _tokenDecimals);

        // Burn all YES and NO tokens
        yesToken.burnFrom(msg.sender, yesBalance);
        noToken.burnFrom(msg.sender, noBalance);

        paymentToken.safeTransfer(msg.sender, paymentTokenAmount);
        emit WithdrawnFromCanceledMarket(msg.sender, yesBalance, noBalance, paymentTokenAmount);
    }

    function settleBonds() external notPaused nonReentrant {
        _settleBonds();
    }

    // External view functions ////////////////////////////////////////

    function positionCount() external pure returns (uint256) {
        // _YES, _NO, _CANCELED
        return 3;
    }

    function getUserClaimableAmount(address _account) public view returns (uint256) {
        uint256 winningTokenBalance;
        if (winningPosition == _YES) {
            winningTokenBalance = yesToken.balanceOf(_account);
        } else if (winningPosition == _NO) {
            winningTokenBalance = noToken.balanceOf(_account);
        } else if (winningPosition == _CANCELED) {
            winningTokenBalance = (yesToken.balanceOf(_account) + noToken.balanceOf(_account)) / 2;
        } else {
            return 0; // if market is cancelled, user cannot claim through redeem(). Use withdrawFromCanceledMarket() or burn() instead.
        }

        uint256 claimableAmount = winningTokenBalance * (10 ** _paymentTokenDecimals) / (10 ** _tokenDecimals);

        return claimableAmount;
    }

    function getAllAmounts() external view returns (uint256, uint256, uint256) {
        return (resolverBondAmount, disputerBondAmount, escalatorBondAmount);
    }

    function getCurrentStatus() public view returns (MarketStatus) {
        MarketStatus currentState = currentStatus;

        if (currentState == MarketStatus.Created && block.timestamp > endOfTrading) {
            return MarketStatus.OpenForResolution;
        }

        if (
            currentState == MarketStatus.ResolutionProposed
                && block.timestamp > resolutionProposedAt + firstChallengePeriod
        ) {
            return MarketStatus.Finalized;
        }

        if (currentState == MarketStatus.SetByCouncil && block.timestamp > councilDecisionAt + secondChallengePeriod) {
            return MarketStatus.Finalized;
        }

        if (currentState == MarketStatus.ResetByCouncil && block.timestamp > councilDecisionAt + secondChallengePeriod)
        {
            return MarketStatus.OpenForResolution;
        }

        return currentState;
    }

    function getUserPosition(address user) external view returns (uint256 yesAmount, uint256 noAmount) {
        yesAmount = yesToken.balanceOf(user);
        noAmount = noToken.balanceOf(user);
    }

    function getPoolAddresses() external view returns (address, address) {
        return (yesPool, noPool);
    }

    // Public functions ////////////////////////////////////////////////

    // Internal functions //////////////////////////////////////////////

    function _updateStatus(MarketStatus _newStatus, uint256 _outcome) internal {
        MarketStatus _currentState = getCurrentStatus();
        if (!_isValidTransition(_currentState, _newStatus)) {
            revert InvalidStatusTransition(_currentState, _newStatus);
        }
        currentStatus = _newStatus;
        statusHistory.push(StatusChange(_newStatus, block.timestamp, _outcome));
        emit MarketStatusUpdated(_currentState, _newStatus, _outcome);
    }

    // This function is used when getCurrentStatus() is finalized
    // but the currentStatus is not yet set to finalized
    // e.g., when market reaches finalized via challenge period ends
    function _setStatusToFinalized(uint256 _outcome) internal {
        MarketStatus _currentStatus = currentStatus;
        currentStatus = MarketStatus.Finalized;
        finalizedAt = block.timestamp;
        emit MarketStatusUpdated(_currentStatus, MarketStatus.Finalized, _outcome);
    }

    // Private functions //////////////////////////////////////////////

    function _initializeWithParameters(
        string memory _marketQuestion,
        string memory _marketSource,
        string memory _additionalInfo,
        uint256 _endOfTrading,
        uint256 _yesNoTokenCap
    ) private {
        createdAt = block.timestamp;
        marketQuestion = _marketQuestion;
        marketSource = _marketSource;
        additionalInfo = _additionalInfo;
        endOfTrading = _endOfTrading;
        yesNoTokenCap = _yesNoTokenCap;
    }

    function _transferReward(address _receiver) private notPaused {
        if (rewardAmount == 0) {
            return;
        }

        bool isBlacklisted = false;
        try IBlacklistable(address(rewardToken)).isBlacklisted(_receiver) returns (bool result) {
            isBlacklisted = result;
        } catch {
            // interface not implemented or call failed, treat as not blacklisted
            isBlacklisted = false;
        }

        if (isBlacklisted) {
            rewardToken.safeTransfer(marketManager.safeBoxAddress(), rewardAmount);
            emit RewardReceiverBlacklisted(address(rewardToken), _receiver);
        } else {
            rewardToken.safeTransfer(_receiver, rewardAmount);
        }
    }

    function _settleBonds() private {
        if (getCurrentStatus() != MarketStatus.Finalized) {
            revert MarketNotFinalized();
        }
        if (bondSettled) {
            revert BondsAlreadySettled();
        }

        if (escalatedDisputeAt > 0) {
            EscalatedDispute memory lastEscalation = escalation.getEscalatedDispute(address(this));
            IOracleCouncil.Dispute memory lastDispute = oracleCouncil.getLastClosedDispute(address(this));
            _handleBondsForEscalation(lastEscalation, lastDispute);

            if (lastEscalation.resultWinningPosition == _CANCELED) {
                _transferReward(marketManager.safeBoxAddress());
            } else if (lastEscalation.resultWinningPosition == lastDispute.originalOutcomeFromResolver) {
                _transferReward(marketManager.resolverAddress(address(this)));
            } else {
                _transferReward(lastDispute.disputorAddress);
            }
        } else if (councilDecisionAt > 0) {
            IOracleCouncil.Dispute memory lastDispute = oracleCouncil.getLastClosedDispute(address(this));

            if (lastDispute.isResolverPunished) {
                oracleBonds.sendBondFromMarketToSafeBox(
                    address(this), BondConstants.RESOLVER_BOND, lastDispute.disputorAddress
                );
            } else {
                oracleBonds.issueBondsBackToResolver(address(this));
            }

            if (lastDispute.isDisputorPunished) {
                oracleBonds.sendBondFromMarketToSafeBox(
                    address(this), BondConstants.DISPUTOR_BOND, lastDispute.disputorAddress
                );
            } else {
                oracleBonds.issueBondsBackToDisputor(address(this), lastDispute.disputorAddress);
            }

            if (lastDispute.winningPosition == _CANCELED) {
                _transferReward(marketManager.safeBoxAddress());
            } else if (lastDispute.winningPosition == lastDispute.originalOutcomeFromResolver) {
                _transferReward(marketManager.resolverAddress(address(this)));
            } else {
                _transferReward(lastDispute.disputorAddress);
            }
        } else {
            oracleBonds.issueBondsBackToResolver(address(this));
            if (winningPosition == _CANCELED) {
                _transferReward(marketManager.safeBoxAddress());
            } else {
                _transferReward(marketManager.resolverAddress(address(this)));
            }
        }

        bondSettled = true;
        emit BondsSettled(address(this), winningPosition);
    }

    function _isValidTransition(MarketStatus from, MarketStatus to) private view returns (bool) {
        if (from == MarketStatus.Created) {
            return to == MarketStatus.OpenForResolution && block.timestamp > endOfTrading;
        }

        if (from == MarketStatus.OpenForResolution) {
            return to == MarketStatus.ResolutionProposed;
        }

        if (from == MarketStatus.ResolutionProposed) {
            if (block.timestamp <= resolutionProposedAt + firstChallengePeriod) {
                return to == MarketStatus.DisputeRaised;
            } else {
                return to == MarketStatus.Finalized;
            }
        }

        if (from == MarketStatus.DisputeRaised) {
            return to == MarketStatus.SetByCouncil || to == MarketStatus.ResetByCouncil
                || to == MarketStatus.OpenForResolution;
        }

        if (from == MarketStatus.SetByCouncil) {
            if (block.timestamp <= councilDecisionAt + secondChallengePeriod) {
                return to == MarketStatus.EscalatedDisputeRaised;
            } else {
                return to == MarketStatus.Finalized;
            }
        }

        if (from == MarketStatus.ResetByCouncil) {
            if (block.timestamp <= councilDecisionAt + secondChallengePeriod) {
                return to == MarketStatus.EscalatedDisputeRaised;
            } else {
                return to == MarketStatus.OpenForResolution;
            }
        }

        if (from == MarketStatus.EscalatedDisputeRaised) {
            return to == MarketStatus.Finalized || to == MarketStatus.OpenForResolution;
        }

        return false;
    }

    function _handleBondsForEscalation(
        EscalatedDispute memory lastEscalation,
        IOracleCouncil.Dispute memory lastDispute
    ) private {
        if (lastEscalation.isOriginalResolverPunished) {
            oracleBonds.sendBondFromMarketToSafeBox(
                address(this), BondConstants.RESOLVER_BOND, lastDispute.disputorAddress
            );
        } else {
            oracleBonds.issueBondsBackToResolver(address(this));
        }

        if (lastEscalation.isCouncilDisputorPunished) {
            oracleBonds.sendBondFromMarketToSafeBox(
                address(this), BondConstants.DISPUTOR_BOND, lastDispute.disputorAddress
            );
        } else {
            oracleBonds.issueBondsBackToDisputor(address(this), lastDispute.disputorAddress);
        }

        if (lastEscalation.isEscalatedDisputorPunished) {
            oracleBonds.sendBondFromMarketToSafeBox(
                address(this), BondConstants.ESCALATED_DISPUTOR_BOND, lastEscalation.escalatedDisputorAddress
            );
        } else {
            oracleBonds.issueBondsBackToEscalatedDisputor(address(this));
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.5.0;

/// @title The interface for the Uniswap V3 Factory
/// @notice The Uniswap V3 Factory facilitates creation of Uniswap V3 pools and control over the protocol fees
interface IUniswapV3Factory {
    /// @notice Emitted when the owner of the factory is changed
    /// @param oldOwner The owner before the owner was changed
    /// @param newOwner The owner after the owner was changed
    event OwnerChanged(address indexed oldOwner, address indexed newOwner);

    /// @notice Emitted when a pool is created
    /// @param token0 The first token of the pool by address sort order
    /// @param token1 The second token of the pool by address sort order
    /// @param fee The fee collected upon every swap in the pool, denominated in hundredths of a bip
    /// @param tickSpacing The minimum number of ticks between initialized ticks
    /// @param pool The address of the created pool
    event PoolCreated(
        address indexed token0,
        address indexed token1,
        uint24 indexed fee,
        int24 tickSpacing,
        address pool
    );

    /// @notice Emitted when a new fee amount is enabled for pool creation via the factory
    /// @param fee The enabled fee, denominated in hundredths of a bip
    /// @param tickSpacing The minimum number of ticks between initialized ticks for pools created with the given fee
    event FeeAmountEnabled(uint24 indexed fee, int24 indexed tickSpacing);

    /// @notice Returns the current owner of the factory
    /// @dev Can be changed by the current owner via setOwner
    /// @return The address of the factory owner
    function owner() external view returns (address);

    /// @notice Returns the tick spacing for a given fee amount, if enabled, or 0 if not enabled
    /// @dev A fee amount can never be removed, so this value should be hard coded or cached in the calling context
    /// @param fee The enabled fee, denominated in hundredths of a bip. Returns 0 in case of unenabled fee
    /// @return The tick spacing
    function feeAmountTickSpacing(uint24 fee) external view returns (int24);

    /// @notice Returns the pool address for a given pair of tokens and a fee, or address 0 if it does not exist
    /// @dev tokenA and tokenB may be passed in either token0/token1 or token1/token0 order
    /// @param tokenA The contract address of either token0 or token1
    /// @param tokenB The contract address of the other token
    /// @param fee The fee collected upon every swap in the pool, denominated in hundredths of a bip
    /// @return pool The pool address
    function getPool(
        address tokenA,
        address tokenB,
        uint24 fee
    ) external view returns (address pool);

    /// @notice Creates a pool for the given two tokens and fee
    /// @param tokenA One of the two tokens in the desired pool
    /// @param tokenB The other of the two tokens in the desired pool
    /// @param fee The desired fee for the pool
    /// @dev tokenA and tokenB may be passed in either order: token0/token1 or token1/token0. tickSpacing is retrieved
    /// from the fee. The call will revert if the pool already exists, the fee is invalid, or the token arguments
    /// are invalid.
    /// @return pool The address of the newly created pool
    function createPool(
        address tokenA,
        address tokenB,
        uint24 fee
    ) external returns (address pool);

    /// @notice Updates the owner of the factory
    /// @dev Must be called by the current owner
    /// @param _owner The new owner of the factory
    function setOwner(address _owner) external;

    /// @notice Enables a fee amount with the given tickSpacing
    /// @dev Fee amounts may never be removed once enabled
    /// @param fee The fee amount to enable, denominated in hundredths of a bip (i.e. 1e-6)
    /// @param tickSpacing The spacing between ticks to be enforced for all pools created with the given fee amount
    function enableFeeAmount(uint24 fee, int24 tickSpacing) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";

contract YesNoToken is ERC20, Ownable, ERC20Burnable {
    constructor(string memory name, string memory symbol) ERC20(name, symbol) {}

    /// @notice Mints new tokens to a specified address
    /// @param to The address to mint tokens to
    /// @param amount The amount of tokens to mint
    /// @dev Only callable by the owner of the contract
    function mint(address to, uint256 amount) public onlyOwner {
        _mint(to, amount);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";

// Inheritance
import "./interfaces/ITruthMarketManager.sol";
import "./libraries/Roles.sol";

// Clone of syntetix contract without constructor

contract OraclePausable is OwnableUpgradeable {
    uint public lastPauseTime;
    bool public paused;

    /// @notice Changes the paused state of the contract
    /// @param _paused The new paused state to set
    /// @dev Only callable by addresses with PAUSER_ROLE or the owner. Only Protocol DAO can unpause
    function setPaused(bool _paused) external pauserOnly {
        // Ensure we're actually changing the state before we do anything
        if (_paused == paused) {
            return;
        }
        if (paused) {
            require(msg.sender == ITruthMarketManager(owner()).owner(), "Only Protocol DAO can unpause");
        }
        // Set our paused state.
        paused = _paused;

        // If applicable, set the last pause time.
        if (paused) {
            lastPauseTime = block.timestamp;
        }

        // Let everyone know that our pause state has changed.
        emit PauseChanged(paused);
    }

    event PauseChanged(bool isPaused);

    modifier notPaused() {
        require(!ITruthMarketManager(owner()).paused(), "Manager paused.");
        require(!paused, "Contract is paused");
        _;
    }

    modifier pauserOnly() {
        require(
            ITruthMarketManager(owner()).hasRole(Roles.PAUSER_ROLE, msg.sender) ||
                owner() == msg.sender,
            "Non-pauser address"
        );
        _;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

enum MarketStatus {
    Created,                // 0
    OpenForResolution,      // 1
    ResolutionProposed,     // 2
    DisputeRaised,          // 3
    SetByCouncil,           // 4
    ResetByCouncil,         // 5
    EscalatedDisputeRaised, // 6
    Finalized               // 7
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

library BondConstants {
    uint public constant RESOLVER_BOND = 101;
    uint public constant DISPUTOR_BOND = 102;
    uint public constant ESCALATED_DISPUTOR_BOND = 103;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "./EscalationEnums.sol";

struct EscalatedDispute {
    address escalatedDisputorAddress;
    string disputeString;
    string escalationProposalId;
    EscalationStatus escalationStatus;
    EscalationResult escalationResult;
    uint256 resultWinningPosition;
    uint256 createdAt;
    uint256 resolvedAt;
    bool isEscalatedDisputorPunished;
    bool isCouncilDisputorPunished;
    bool isOriginalResolverPunished;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface ITruthMarketManager {
    /* ========== VIEWS / VARIABLES ========== */
    function paused() external view returns (bool);

    function getActiveMarketAddress(uint256 _index) external view returns (address);

    function isActiveMarket(address _marketAddress) external view returns (bool);

    function numberOfActiveMarkets() external view returns (uint256);

    function resolverBondAmount() external view returns (uint256);

    function disputerBondAmount() external view returns (uint256);

    function escalatorBondAmount() external view returns (uint256);

    function paymentToken() external view returns (address);

    function owner() external view returns (address);

    function oracleBonds() external view returns (address);

    function oracleCouncilAddress() external view returns (address);

    function escalationAddress() external view returns (address);

    function safeBoxAddress() external view returns (address);

    function uniswapV3Factory() external view returns (address);

    function creatorAddress(address _market) external view returns (address);

    function resolverAddress(address _market) external view returns (address);

    function isPauserAddress(address _pauserAddress) external view returns (bool);

    function safeBoxPercentage() external view returns (uint256);

    function creatorPercentage() external view returns (uint256);

    function resolverPercentage() external view returns (uint256);

    function firstChallengePeriod() external view returns (uint256);

    function secondChallengePeriod() external view returns (uint256);

    function maxOracleCouncilMembers() external view returns (uint256);

    function yesNoTokenCap() external view returns (uint256);

    function hasRole(bytes32 role, address account) external view returns (bool);

    /* ========== MUTATIVE FUNCTIONS ========== */

    function disputeMarket(address _marketAddress, address disputor) external;

    function escalateDisputeMarket(address _marketAddress, address disputor) external;

    function proposeResolution(address _marketAddress, uint256 _outcomePosition) external;
    function resolveMarketByCouncil(address _marketAddress, uint256 _outcomePosition) external;
    function resolveMarketByEscalation(address _marketAddress, uint256 _outcomePosition) external;

    function resetMarket(address _marketAddress) external;
    function resetMarketByCouncil(address _marketAddress, bool _returnToOpenForResolution) external;
    function resetMarketByEscalation(address _marketAddress) external;

    function setFirstChallengePeriod(address _market, uint256 _firstChallengePeriod) external;

    function setSecondChallengePeriod(address _market, uint256 _secondChallengePeriod) external;

    function setYesNoTokenCap(address _market, uint256 _yesNoTokenCap) external;

    function sendMarketBondAmountTo(address _market, address _recepient, uint256 _amount) external;

    /* ========== OWNER FUNCTIONS ========== */

    function setAddresses(
        address _truthMarketMastercopy,
        address _oracleCouncil,
        address _paymentToken,
        address _safeBox,
        address _uniswapV3Factory,
        address _rewardWallet,
        address _escalation
    ) external;

    function setPercentages(uint256 _safeBoxPercentage, uint256 _creatorPercentage, uint256 _resolverPercentage)
        external;

    function setDurations(
        uint256 _firstChallengePeriod,
        uint256 _secondChallengePeriod,
        uint256 _minimumTradingDuration
    ) external;

    function setLimits(uint256 _maxOracleCouncilMembers) external;

    function setAmounts(
        uint256 _resolverBondAmount,
        uint256 _disputerBondAmount,
        uint256 _escalatorBondAmount,
        uint256 _yesNoTokenCap
    ) external;

    function setOracleBonds(address _oracleBonds) external;

    function createMarket(
        string memory _marketQuestion,
        string memory _marketSource,
        string memory _additionalInfo,
        uint _endOfTrading,
        uint _yesNoTokenCap,
        address _rewardToken,
        uint _rewardAmount,
        string memory _yesTokenSymbol,
        string memory _noTokenSymbol
    ) external;

    function createMarket(
        string memory _marketQuestion,
        string memory _marketSource,
        string memory _additionalInfo,
        uint _endOfTrading,
        uint _yesNoTokenCap,
        address _rewardToken,
        uint _rewardAmount
    ) external;

    function setEndOfTrading(address _market, uint256 _endOfTrading) external;

    function resetMarketStatus(address _market) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../MarketEnums.sol";

interface ITruthMarket {
    /* ========== VIEWS / VARIABLES ========== */

    function winningPosition() external view returns (uint256);
    
    function positionCount() external pure returns (uint256);

    function resolverBondAmount() external view returns (uint256);

    function disputerBondAmount() external view returns (uint256);

    function escalatorBondAmount() external view returns (uint256);
    
    function firstChallengePeriod() external view returns (uint256);

    function secondChallengePeriod() external view returns (uint256);
    
    function getCurrentStatus() external view returns (MarketStatus);
    
    function paused() external view returns (bool);

    function rewardAmount() external view returns (uint256);

    function paymentToken() external view returns (address);
    
    function yesToken() external view returns (address);
    
    function noToken() external view returns (address);
    
    function getPoolAddresses() external view returns (address yesPool, address noPool);
    
    function bondSettled() external view returns (bool);
    
    /* ========== MUTATIVE FUNCTIONS ========== */

    function proposeResolution(uint256 _outcome) external;

    function raiseDispute() external;

    function resolveMarketByCouncil(uint256 _outcome) external;
    
    function resetMarketByCouncil(bool _returnToOpenForResolution) external;

    function raiseEscalatedDispute() external;

    function resolveMarketByEscalation(uint256 _outcome) external;
    
    function resetMarketByEscalation() external;
    
    function setYesNoTokenCap(uint256 _yesNoTokenCap) external;

    function setEndOfTrading(uint256 _endOfTrading) external;

    function setFirstChallengePeriod(uint256 _firstChallengePeriod) external;

    function setSecondChallengePeriod(uint256 _secondChallengePeriod) external;
    
    function mint(uint256 paymentTokenAmount) external;

    function burn(uint256 amount) external;

    function redeem(uint256 amount) external;
    
    function withdrawFromCanceledMarket() external;
    
    function transferRewardToResolver(address _resolver) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface IOracleBonds {
    /* ========== VIEWS / VARIABLES ========== */
    function getTotalDepositedBondAmountForMarket(address _market) external view returns (uint);

    function getClaimedBondAmountForMarket(address _market) external view returns (uint);

    function getClaimableBondAmountForMarket(address _market) external view returns (uint);

    function getDisputorBondForMarket(address _market, address _disputorAddress) external view returns (uint);

    function getResolverBondForMarket(address _market) external view returns (uint);

    function getEscalatedDisputorBondForMarket(address _market) external view returns (uint);

    function sendResolverBondToMarket(
        address _market,
        address _resolverAddress,
        uint _amount
    ) external;

    function sendDisputorBondToMarket(
        address _market,
        address _disputorAddress,
        uint _amount
    ) external;

    function sendEscalatedDisputorBondToMarket(
        address _market,
        address _escalatedDisputorAddress,
        uint _amount
    ) external;

    function sendOpenDisputeBondFromMarketToDisputor(
        address _market,
        address _disputorAddress
    ) external;

    function sendBondFromMarketToSafeBox(
        address _market,
        uint _bondToReduce,
        address _disputorAddress
    ) external;

    function setManagerAddress(address _managerAddress) external;

    function issueBondsBackToResolver(address _market) external;

    function issueBondsBackToEscalatedDisputor(address _market) external;

    function issueBondsBackToDisputor(address _market, address _disputorAddress) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface IOracleCouncil {
    /* ========== VIEWS / VARIABLES ========== */
    function isOracleCouncilMember(address _councilMember) external view returns (bool);

    function isMarketClosedForDisputes(address _market) external view returns (bool);

    function closeMarketForDisputes(address _market) external;

    function isMarketLastClosedDisputeExists(address _market) external view returns (bool);

    function getLastClosedDispute(address _market) external view returns (Dispute memory);

    function reopenMarketForDisputes(address _market) external;

    struct Dispute {
        address disputorAddress;
        string disputeString;
        uint disputeCode;
        uint disputeTimestamp;
        uint originalOutcomeFromResolver;
        uint winningPosition;
        bool isResolverPunished;
        bool isDisputorPunished;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../EscalationEnums.sol";
import "../EscalationStructs.sol";

interface IEscalation {
    /* ========== VIEWS / VARIABLES ========== */
    function isEscalationOpen(address _market) external view returns (bool);

    function getEscalatedDispute(address _market) external view returns (EscalatedDispute memory);

    /* ========== MUTATIVE FUNCTIONS ========== */
    function resetEscalationStatus(address _market) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface IBlacklistable {
    function isBlacklisted(address account) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.0;

import "../ERC20.sol";
import "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, deducting from the caller's
     * allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `amount`.
     */
    function burnFrom(address account, uint256 amount) public virtual {
        _spendAllowance(account, _msgSender(), amount);
        _burn(account, amount);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

library Roles {
    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;
    bytes32 public constant OPERATOR_ROLE = keccak256("OPERATOR_ROLE");
    bytes32 public constant TIMELOCK_ROLE = keccak256("TIMELOCK_ROLE");
    bytes32 public constant PAUSER_ROLE = keccak256("PAUSER_ROLE");
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

enum EscalationStatus {
    None, // not initiated yet
    Initialized,
    Voting,
    Resolved
}
enum EscalationResult {
    None, // no outcome yet
    Accepted, // accept dispute & set outcome (YES/NO/CANCEL) 
    Reset, // accept dispute & reset outcome
    Rejected // reject dispute
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

{
  "remappings": [
    "ds-test/=lib/ds-test/src/",
    "forge-std/=lib/forge-std/src/",
    "@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    "@openzeppelin/contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/contracts/",
    "@openzeppelin-foundry-upgrades/=lib/openzeppelin-foundry-upgrades/src/",
    "@uniswap/v3-core/contracts/=lib/v3-core/contracts/",
    "@uniswap/permit2/=lib/permit2/src/",
    "@uniswap/swap-router-contracts/=lib/swap-router-contracts/contracts/",
    "@ERC721A/=lib/ERC721A/contracts/",
    "ERC721A/=lib/ERC721A/contracts/",
    "erc4626-tests/=lib/openzeppelin-contracts-upgradeable/lib/erc4626-tests/",
    "forge-gas-snapshot/=lib/permit2/lib/forge-gas-snapshot/src/",
    "openzeppelin-contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/",
    "openzeppelin-contracts/=lib/openzeppelin-contracts/",
    "openzeppelin-foundry-upgrades/=lib/openzeppelin-foundry-upgrades/src/",
    "openzeppelin/=lib/openzeppelin-contracts-upgradeable/contracts/",
    "permit2/=lib/permit2/",
    "solidity-stringutils/=lib/openzeppelin-foundry-upgrades/lib/solidity-stringutils/",
    "solmate/=lib/permit2/lib/solmate/",
    "swap-router-contracts/=lib/swap-router-contracts/contracts/",
    "v3-core/=lib/v3-core/"
  ],
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "metadata": {
    "useLiteralContent": false,
    "bytecodeHash": "ipfs",
    "appendCBOR": true
  },
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  },
  "evmVersion": "cancun",
  "viaIR": true,
  "libraries": {}
}

[{"inputs":[],"name":"BondsAlreadySettled","type":"error"},{"inputs":[],"name":"InvalidAddress","type":"error"},{"inputs":[],"name":"InvalidBondAmount","type":"error"},{"inputs":[],"name":"InvalidChallengePeriod","type":"error"},{"inputs":[{"internalType":"uint256","name":"outcome","type":"uint256"}],"name":"InvalidOutcome","type":"error"},{"inputs":[{"internalType":"enum MarketStatus","name":"from","type":"uint8"},{"internalType":"enum MarketStatus","name":"to","type":"uint8"}],"name":"InvalidStatusTransition","type":"error"},{"inputs":[],"name":"MarketFinalized","type":"error"},{"inputs":[],"name":"MarketNotCanceled","type":"error"},{"inputs":[],"name":"MarketNotDisputed","type":"error"},{"inputs":[],"name":"MarketNotFinalized","type":"error"},{"inputs":[],"name":"MarketNotInTradingPhase","type":"error"},{"inputs":[],"name":"NoTokensToWithdraw","type":"error"},{"inputs":[],"name":"TokenCapExceeded","type":"error"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"market","type":"address"},{"indexed":false,"internalType":"uint256","name":"winningPosition","type":"uint256"}],"name":"BondsSettled","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"endOfTrading","type":"uint256"}],"name":"EndOfTradingChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"firstChallengePeriod","type":"uint256"}],"name":"FirstChallengePeriodChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint8","name":"version","type":"uint8"}],"name":"Initialized","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"enum MarketStatus","name":"from","type":"uint8"},{"indexed":false,"internalType":"enum MarketStatus","name":"to","type":"uint8"},{"indexed":false,"internalType":"uint256","name":"outcome","type":"uint256"}],"name":"MarketStatusUpdated","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"previousOwner","type":"address"},{"indexed":true,"internalType":"address","name":"newOwner","type":"address"}],"name":"OwnershipTransferred","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"bool","name":"isPaused","type":"bool"}],"name":"PauseChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"token","type":"address"},{"indexed":true,"internalType":"address","name":"account","type":"address"}],"name":"RewardReceiverBlacklisted","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"secondChallengePeriod","type":"uint256"}],"name":"SecondChallengePeriodChanged","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"user","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"TokensBurned","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"user","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"TokensMinted","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"user","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"TokensRedeemed","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"user","type":"address"},{"indexed":false,"internalType":"uint256","name":"yesAmount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"noAmount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"paymentAmount","type":"uint256"}],"name":"WithdrawnFromCanceledMarket","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"yesNoTokenCap","type":"uint256"}],"name":"YesNoTokenCapChanged","type":"event"},{"inputs":[],"name":"POOL_FEE","outputs":[{"internalType":"uint24","name":"","type":"uint24"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"VERSION","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"additionalInfo","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"bondSettled","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"burn","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"councilDecisionAt","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"createdAt","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"currentStatus","outputs":[{"internalType":"enum MarketStatus","name":"","type":"uint8"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"disputedAt","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"disputerBondAmount","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"endOfTrading","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"escalatedDisputeAt","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"escalation","outputs":[{"internalType":"contract IEscalation","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"escalatorBondAmount","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"finalizedAt","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"firstChallengePeriod","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"getAllAmounts","outputs":[{"internalType":"uint256","name":"","type":"uint256"},{"internalType":"uint256","name":"","type":"uint256"},{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"getCurrentStatus","outputs":[{"internalType":"enum MarketStatus","name":"","type":"uint8"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"getPoolAddresses","outputs":[{"internalType":"address","name":"","type":"address"},{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"_account","type":"address"}],"name":"getUserClaimableAmount","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"user","type":"address"}],"name":"getUserPosition","outputs":[{"internalType":"uint256","name":"yesAmount","type":"uint256"},{"internalType":"uint256","name":"noAmount","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"string","name":"_marketQuestion","type":"string"},{"internalType":"string","name":"_marketSource","type":"string"},{"internalType":"string","name":"_additionalInfo","type":"string"},{"internalType":"uint256","name":"_endOfTrading","type":"uint256"},{"internalType":"uint256","name":"_yesNoTokenCap","type":"uint256"},{"internalType":"address","name":"_paymentToken","type":"address"},{"internalType":"address","name":"_yesToken","type":"address"},{"internalType":"address","name":"_noToken","type":"address"},{"internalType":"address","name":"_rewardToken","type":"address"},{"internalType":"uint256","name":"_rewardAmount","type":"uint256"}],"name":"initialize","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"lastPauseTime","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"marketManager","outputs":[{"internalType":"contract ITruthMarketManager","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"marketQuestion","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"marketSource","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"paymentTokenAmount","type":"uint256"}],"name":"mint","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"noPool","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"noToken","outputs":[{"internalType":"contract YesNoToken","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"oracleBonds","outputs":[{"internalType":"contract IOracleBonds","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"oracleCouncil","outputs":[{"internalType":"contract IOracleCouncil","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"owner","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"paused","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"paymentToken","outputs":[{"internalType":"contract IERC20Metadata","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"positionCount","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"pure","type":"function"},{"inputs":[{"internalType":"uint256","name":"_outcome","type":"uint256"}],"name":"proposeResolution","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"raiseDispute","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"raiseEscalatedDispute","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"redeem","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"renounceOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bool","name":"_returnToOpenForResolution","type":"bool"}],"name":"resetMarketByCouncil","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"resetMarketByEscalation","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"resolutionProposedAt","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"_outcome","type":"uint256"}],"name":"resolveMarketByCouncil","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"_outcome","type":"uint256"}],"name":"resolveMarketByEscalation","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"resolverBondAmount","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"rewardAmount","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"rewardToken","outputs":[{"internalType":"contract IERC20","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"secondChallengePeriod","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"_endOfTrading","type":"uint256"}],"name":"setEndOfTrading","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"_firstChallengePeriod","type":"uint256"}],"name":"setFirstChallengePeriod","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"bool","name":"_paused","type":"bool"}],"name":"setPaused","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"_secondChallengePeriod","type":"uint256"}],"name":"setSecondChallengePeriod","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"_yesNoTokenCap","type":"uint256"}],"name":"setYesNoTokenCap","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"settleBonds","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"uint256","name":"","type":"uint256"}],"name":"statusHistory","outputs":[{"internalType":"enum MarketStatus","name":"status","type":"uint8"},{"internalType":"uint256","name":"timestamp","type":"uint256"},{"internalType":"uint256","name":"outcome","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"newOwner","type":"address"}],"name":"transferOwnership","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"winningPosition","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"withdrawFromCanceledMarket","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"yesNoTokenCap","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"yesPool","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"yesToken","outputs":[{"internalType":"contract YesNoToken","name":"","type":"address"}],"stateMutability":"view","type":"function"}]